:'(没有人知道吗

#name 唐门宏@多刀流
#tip 爱与正义唐门宏YYL版-11.26

--↓说明和广告，此句可删除↓--
#hello $name，欢迎使用爱与正义的唐门宏，如有问题请在论坛上联系我，你要玄李n合一服的......可以直接来笑梦诗雨情找我。

#delay 2

#icon 3182
#varnum v_战斗模式,3,tip:战斗模式,tip_1:带开场准备（不自动开怪）,tip_2:无开场准备,tip_3:无千机变(田螺用),icon_1:3197,icon_2:3191,icon_3:14
#varnum v_扶摇,2,tip:扶摇,tip_1:站立,tip_2:扶摇,icon_1:533,icon_2:1485
#varbool v_爆发,tip:爆发,tip_1:开,tip_2:关,icon:3222
#varnum v_群怪,3,tip:群怪模式,tip_1:正常,tip_2:智能群怪,tip_3:不群怪,icon_1:3190,icon_2:3230,icon_3:3177
#varbool  v_wq,tip:多刀流模式,tip_1:开启状态,tip_2:关闭状态,icon:4926

--↓自定义变量↓--

--换武器--
/if [v_wq] --多刀流
/omwp [buff:6394]射凰弩
/omwp [nobuff:6394]蛟搏
/end

--↓自定义变量↓--

/var [sklv:梨花带雨=1]v_大暴雨模式
/var [sklv:无声骤雨=1,sklv:梨花带雨=0]v_暴雨模式
/var [sklv:积重难返=1,sklv:击搏挽裂=1]v_鸡蛋模式

/var [ota:蚀肌弹,v_大暴雨模式,sklv:无声骤雨=1,(buff:奥妙;buff:心无旁骛,ota:蚀肌弹<0.5);ota:夺魄箭,sklv:无声骤雨=1,nocd:追命箭,buff:追命无声,ota:夺魄箭<0.4]v_打断

/var [mount:天罗诡道,(!v_群怪=3,tstate:stand,(nocd:天绝地灭;vbomb<3,nocd:暗藏杀机,buff:心无旁骛);puppet<=3,tm<65;nopuppet,tm<65;puppet<6,buff:奥妙;v_暴雨模式,nobuff:心无旁骛);v_大暴雨模式,buff:心无旁骛|奥妙;nobuff:心无旁骛,nobuff:奥妙,nobuff:扬威,tnombuff:化血镖;v_鸡蛋模式,(nobuff:气魄;tm<55)]v_填充去死

/var [mount:天罗诡道,(!v_群怪=3,nopuppet;tstate:stand,vbomb<3,nocd:暗藏杀机,(v_暴雨模式,tm>65;buff:心无旁骛));v_暴雨模式,buff:心无旁骛;mount:惊羽诀,!v_大暴雨模式,(tnombuff:化血镖|穿心弩)]v_暴雨去死吧

--↓战前准备及开场爆发↓--
/if [!fight,v_战斗模式=1]
     /skill [!v_群怪=3,vbomb<3,tar]暗藏杀机
     /skill [!lastota:千机变,!tar:岳承志,!tar:闻人彦范,(nopuppet;pupmdis>5)]千机变
/end

/if [!fight,v_战斗模式=1,mount:惊羽诀]
      /skill [nofight]追命箭
      /skill [nofight,ota:追命箭>0.8]打断
/end

/return [!fight,v_战斗模式=1]

--↓打断命令↓--
/skill [target:卓力格图,nobuff:镇山河,tprepare:掷锤>0.5] 后跳
/skill [v_打断]打断
/return [ota]


--↓千机变↓--

/if [!lastota:千机变,mount:天罗诡道,(state:stand,!puppet,!v_战斗模式=3;puptdis>25,dis<25,tstate:stand;puppet:连弩<=3;puppet:连弩<9,buff:奥妙)]
     /skill 千机变
/end

/if [puppet<9,buff:奥妙,!v_战斗模式=3]
     /skill [!lastota:千机变,state:stand]千机变
/return
/end

    /skill [puppet:连弩;puppet,ota]攻击
/if [puppet:底座]
     /skill [puppet:底座]连弩形态
/end

--↓爆发↓--

/if [puppet,nobuff:鬼斧神工;mount:惊羽诀]
     /skill [fight,bomb=3,tlife>0.98]图穷匕见
     /skill [tar,puppet:连弩>=33,state:stand,v_爆发,nobuff:心无旁骛,sktest:鬼斧神工,(buff:气魄;v_大暴雨模式)]鬼斧神工
/return [ota]
     /skill [v_爆发,(state:stand,cdtime:鬼斧神工>=1.5,cdtime:鬼斧神工<118,buff:气魄;buff:扬威;pupmdis>=5,tm<30;tmbuff:穿心弩,tmbuff:化血镖,buff:追命无声)]心无旁骛
/end
/return [!fight,v_战斗模式=1;ota]


--↓打断腰坠和扶摇↓--
    /skill [sklv:梅花针=1,tprepare:无懈可击|天音化物|雨钓江秋|火舞金钢|阴阳双流|龙甩尾|薛家剑法|怒吼]梅花针

    /skill [buff:心无旁骛]腰坠

    /skill [v_扶摇=2]扶摇直上

--↓群怪技能↓
     /skill [!v_群怪=3,tstate:stand,mount:天罗诡道]天绝地灭
/if [v_群怪=2,temdis:10>2,nobuff:收队,mount:天罗诡道]
     /skill [tm>=60;puppet]天女散花
     /skill [bomb=3]图穷匕见
     /skill [vbomb<3,nobuff:奥妙]暗藏杀机
/end

/if [v_群怪=2,temdis:10>2,nobuff:收队,mount:惊羽诀]
    /skill [sklv:暴雨梨花=1]暴雨梨花针
    /skill [sklv:裂石穿云=0]裂石弩
/end

--↓追命和逐星↓--

/if [mount:惊羽诀]   
      /skill [buff:追命无声]追命箭
      /skill [tnombuff:穿心弩,nobuff:奥妙,nobuff:心无旁骛]穿心弩
      /return [buff:追命无声,nocd:心无旁骛]
      /skill [sklv:浴血沁骨=1,tmbuff:化血镖,tmbuff:穿心弩;tm<50,nobuff:奥妙]逐星箭
/end

--↓暴雨鸡蛋和夺魄↓--

/if [!v_暴雨去死吧]
     /skill [mount:惊羽诀,(v_大暴雨模式,(tm>70;buff:奥妙|心无旁骛));mount:天罗诡道,(v_暴雨模式,nobuff:心无旁骛;v_大暴雨模式,buff:奥妙|心无旁骛;nobuff:气魄;!v_大暴雨模式,tm<50)]暴雨梨花针
/return [ota]
/end

/if [!v_填充去死]
     /skill [mount:天罗诡道]蚀肌弹
     /skill [mount:惊羽诀]夺魄箭
/end


--↓DOT和蛋↓--

/if [nobuff:鬼斧神工]

     /skill [tnombuff:化血镖,nobuff:心无旁骛,nobuff:奥妙]化血镖
     /skill [sklv:卸元箭=1,nobuff:心无旁骛,nobuff:奥妙,(tnobuff:卸甲,tnobuff:万剑归宗)]卸元箭
     /skill [tnombuff:穿心弩,nobuff:奥妙,nobuff:心无旁骛]穿心弩
     /skill [mount:天罗诡道,!v_群怪=3,vbomb<3,tstate:stand,(buff:心无旁骛;v_暴雨模式,tm>=65);nobuff:奥妙,!v_群怪=3,tstate:stand,vbomb<3,(tm>=85;buff:心无旁骛;vbomb=2,tm>=55;cdtime:心无旁骛<8,tm>=55;puppet,cdtime:心无旁骛<2,cdtime:天绝地灭>=1.5)]暗藏杀机
     /skill [bomb=3,(tm<76;buff:心无旁骛|扬威|弩心|朝圣|4759;v_群怪=2,temdis:10>2)]图穷匕见
/return [ota]
/end

/if [puppet,nobuff:鬼斧神工]
     /skill [vbomb=3,cdtime:心无旁骛>=3,(buff:心无旁骛|扬威|朝圣);nobuff:心无旁骛,nobuff:奥妙,vbomb>0,tm<20,cdtime:心无旁骛>10]图穷匕见
/end
     /skill [vbomb>1,(buff:鬼斧神工,nobuff:心无旁骛,bufftime:鬼斧神工<1.5;buff:心无旁骛,nobuff:鬼斧神工,bufftime:心无旁骛<1.5;tstate:run)]图穷匕见


--↓移动战相关↓--
/if [state:run|jump,mount:天罗诡道]
     /skill [!v_群怪=3,vbomb<3,tstate:stand]暗藏杀机
     /skill [bomb=3]图穷匕见
     /skill [tm>70,!v_群怪=3]天女散花
/end

/if [state:run|jump,mount:惊羽诀]
     /skill [sklv:箭雨如潮|裂石穿云=1;tm>=50]裂石弩
/end

可以来试试我的掏裆天罗宏

自动切换武器是可以用的，但是偶尔发生不可以用的情况多数都是因为跟盒子冲突，具体是盒子哪个导致的不太清楚，总之盒子只选少量特别需要的安装的话就没事。